GNUplot - Problem mit Plot

[rene22]

Hi, kennt sich jmd mit GNUplot aus?

Folgender Code soll geplottet werden:

set terminal png
set title "Fuzzygewichtung bei einer Drehzahl von 0-3000 U/Min"
set xrange [0:3000]
set xlabel "Drehzahl [U/Min]"
set ylabel "Gewichtung"
set output "fuzzydrehzahl.png"
set grid nopolar
set key right bottom

set grid xtics nomxtics ytics nomytics noztics nomztics \
 nox2tics nomx2tics noy2tics nomy2tics nocbtics nomcbtics
set grid layerdefault   linetype 0 linewidth 0.25,  linetype 0 linewidth 0.25
s_0(x,a,ep) = 0
s_1(x,a,ep) = 2*((x-a+ep)/(2*ep))**2
s_2(x,a,ep) = 1-(2*((a-x+ep)/(2*ep))**2)
s_3(x,a,ep) = 1
s(x,a,ep)= (x<=a-ep)?         s_0(x,a,ep):  \
           (x > a-ep && x<a)? s_1(x,a,ep):  \
           (x>a && x<a+ep) ?  s_2(x,a,ep):  \
                              s_3(x,a,ep)
unset label
plot (1-s(x,900,900))**2 title "sehr langsam", \
      1-s(x,900,900) title "langsam", \
      1-((1-s(x,900,900))**2) title "mittel langsam", \
      sqrt(s(x,1800,900)) title "etwas schnell", \
      s(x,1800,900) title "schnell", \
      (s(x,1800,900)**2) title "sehr schnell"

Wenn ich das Plotte erscheint der Graph wunderprächtig, jedoch wird auf der X-Skala, die von 0 - 3000 geht, am rechten Rand die letzte Null abgeschnitten, sodass sie nur noch halb zu sehen ist. Also quasi 300( , wenn () als 0 zu vergleichen ist.

Hat jmd eine Idee, wie man den Plot quasi erweitern könnte?

[BLUESCREEN3D]

Bei mir wird die Null nicht abgeschnitten (gnuplot 4.0).
Die Einheit "min" schreibt man übrigens klein.

[rene22]

hmmm, lässt du es dir auch als *.png ausgeben?

Ich benutze Version 4.2 patchlevel 4...

also bei mir schneidets die 0 als in der mitte durch. Könntest du mir vlt. deine *.png schicken, mit angepasstem U/min ?

schau ich mir dir *.plt Datei an, ist die Null nicht abgeschnitte, komischerweise immer nur bei der *.png
Um das in Latex einzubinden benötige ich aber *.png und mach ich ein Screenshot davon, ist die Quali. zu schlecht

[rene22]

ok mit

set rmargin screen 0.80

hats geklappt

[BLUESCREEN3D]

Wenn du das ganze für Latex brauchst, dann willst du es wohl irgendwann Drucken und dafür sollte die Auflösung höher sein, sonst wird der Ausdruck sehr verpixelt.
Am besten wäre es, gleich ein Dateiformat für Vektorgrafiken zu nutzen und keine PNG-Datei zu erstellen.

[vci]

set terminal epslatex

*empfehl*